Google izklājlapas var izmantot ne tikai datu uzkrāšanai un organizēšanai. Varat arī to izmantot, lai noteiktu pašreizējo laiku, izveidotu diagrammas un aprēķinātu vecumu, izmantojot dzimšanas datumu. Pēdējais tiek atklāts, izmantojot formulas un funkcijas, kas iebūvētas tieši Google izklājlapās.
Vecuma noteikšana pēc dzimšanas datuma Google izklājlapās
Izmantojot Google izklājlapas, jums ir divi galvenie veidi, kā noteikt vecumu pēc dzimšanas datuma. Tur ir DATEDIF , kas ir elastīgākā iespēja, un YEARFRAC , jo vienkāršāka izvēle. Līdz raksta beigām jums vajadzētu būt iespējai noteikt ne tikai viena indivīda vecumu, bet arī vairāku dažādu cilvēku grupu vecumu.
Es sākšu lietas ar funkciju DATEDIF.
Funkcija DATEDIF
Lai mēs varētu ienirt pašā funkcijā, mums ir jāzina, kā tā darbojas. Lai to izmantotu ar funkciju DATEDIF, būs jāapgūst sintakse. Katra sadaļa, ko ierakstījāt funkcijā, ir saistīta ar uzdevumu. Skatiet šos uzdevumus tālāk:
Sintakse
=DATEDIF(sākuma_datums,beigu_datums,vienība)
- sākuma datums
- Aprēķins jāsāk ar dzimšanas datumu.
- beigu datums
- Šis būs aprēķina pabeigšanas datums. Nosakot pašreizējo vecumu, šis skaitlis, visticamāk, būs šodienas datums.
- vienība
- Izvades izvēles, kas sastāv no: 'Y', 'M', 'D', 'YM', 'YD' vai 'MD'.
- Y — kopējais pilno gadu skaits, kas pagājuši starp ievadīto sākuma un beigu datumu.
- YM — “M” apzīmē mēnešus. Šī izvade parāda mēnešu skaitu pēc pilnībā pagājušajiem gadiem “Y”. To skaits nepārsniegs 11.
- YD — “D” apzīmē dienas. Šī izvade parāda dienu skaitu pēc pilnībā pagājušajiem gadiem “Y”. To skaits nepārsniegs 364.
- M — kopējais pilnībā pagājušo mēnešu skaits starp ievadīto sākuma un beigu datumu.
- MD — tāpat kā citās vienībās, “D” apzīmē dienas. Šī izvade parāda dienu skaitu pēc pilnībā pagājušajiem mēnešiem “M”. Nevar pārsniegt 30.
- D — kopējais pilnībā pagājušo dienu skaits starp ievadīto sākuma un beigu datumu.
Aprēķins
Tagad, kad jūs saprotat sintaksi, kas tiks izmantota, mēs varam iestatīt formulu. Kā minēts iepriekš, funkcija DATEDIF ir elastīgāka opcija vecuma noteikšanai pēc dzimšanas datuma. Iemesls tam ir tas, ka jūs varat aprēķināt visu informāciju par vecumu gada, mēneša un dienas formātā.
Lai sāktu, šūnā būs nepieciešams datuma paraugs. Esmu nolēmusi noteikt datumu 14.07.1972 šūnā A1 . Mēs izpildīsim formulu šūnā pa labi no tās, B1 , ja vēlaties sekot līdzi, lai uzzinātu par to.
Mēs sāksim ar visvienkāršāko formulas versiju, lai aprēķinātu vecumu. Ja izmantojat iepriekš minēto sintaksi, lai noskaidrotu, kas ir kas, A1 tehniski ir sākuma datums , šodien būs beigu datums , un mēs noteiksim vecumu gados, izmantojot 'Y' . Tāpēc pirmā izmantotā formula izskatīsies šādi:
=datedif(A1,today(),"Y")
Noderīgs padoms: nokopējiet un ielīmējiet formulu tieši B2 un nospiediet taustiņu Enter, lai saņemtu atbilstošo izvadi.
Ja tas izdarīts pareizi, skaitlis, kas norāda aprēķināto vecumu, atradīsies B1 kā “46”.
Izdarīsim to pašu formulu, tikai šoreiz mēs noteiksim vecumu mēnešos “M” 'Y' vietā.
=datedif(A1,today(),"M")
Kopā būtu 559 mēneši. Tas ir 559 mēnešus vecs.
Tomēr šis skaitlis ir mazliet absurds, un es domāju, ka mēs varam to samazināt, izmantojot 'IN' tikai “M” vietā.
kā atlasīt vairākus e - pastus
=datedif(A1,today(),"YM")
Jaunajam rezultātam vajadzētu būt 7, kas ir daudz vieglāk pārvaldāms skaitlis.
Lai būtu rūpīgi, redzēsim, kā izskatīsies dienas, izmantojot gan “YD”, gan “MD”.
=datedif(A1,today(),"YD")
=datedif(A1,today(),"MD")
Šoreiz rezultāti “YD” ir parādīti B1, un rezultāti “MD” atrodas šūnā B2.
Vai esat sapratis to līdz šim?
Tālāk mēs tos visus apvienosim, lai nodrošinātu detalizētāku aprēķinu. Formulas rakstīšana var kļūt nedaudz saspringta, tāpēc vienkārši kopējiet un ielīmējiet norādīto šūnā B1.
Izmantotā formula ir:
=datedif(A1,today(),"Y")&" Years "&datedif(A1,today(),"YM")&" months & "& datedif(A1,today(),"MD")&" days"
Ampersands tiek izmantots, lai savienotu katru formulu kā ķēdes posmu. Tas ir nepieciešams, lai iegūtu pilnu aprēķinu. Jūsu Google izklājlapā ir jābūt tādai pašai formulai kā:
Pilnīgs, detalizēts aprēķins mums ir nodrošinājis 46 gadus, 7 mēnešus un 26 dienas. Varat arī izmantot to pašu formulu, izmantojot funkciju ArrayFormula. Tas nozīmē, ka varat aprēķināt ne tikai vienu datumu, bet arī vairākus datumus.
Esmu nejauši izvēlējies dažus datumus un pievienojis tos papildu šūnām A2-A5 . Izvēlieties savus datumus un nedaudz izklaidējieties. Lai izmantotu funkciju ArrayFormula, kopējiet un ielīmējiet šūnā B1:
=ArrayFormula(datedif(A1:A5,today(),"Y")&" Years "&datedif(A1:A5,today(),"YM")&" months & "& datedif(A1:A5,today(),"MD")&" days")
Šie ir mani rezultāti:
Tagad pieņemsim, ka jūs vēlējāties sakārtot katru datuma daļu atsevišķā mazā slejā. Google izklājlapās pievienojiet sākuma_datumu (dzimšanas datumu) vienā kolonnā un beigu_datumu citā. Savā piemērā esmu izvēlējies šūnu B2 sākuma_datumam un C2 beigu_datumam. Mani datumi ir saistīti ar slavenību Bērta Reinoldsa, Džonija Keša un Lūka Perija dzimšanas un neseno nāvi.
Kā parādīts, kolonnā A ir personas vārds, B kolonnā ir sākuma_datums un C kolonnā beigu_datums. Tagad labajā pusē pievienošu vēl četras kolonnas. Viens katram no “Y”, “YM”, “YD” un visu trīs kombinācijas. Tagad jums vienkārši jāpievieno pareizās formulas katrai slavenības rindai.
Bērts Reinoldss:
=DATEDIF(B2,C2,"Y") Mainiet “Y” uz atbilstošo kolonnu, kuru mēģināt aprēķināt.
Džonijs Kešs:
=DATEDIF(B3,C3,"Y") Mainiet “Y” uz atbilstošo kolonnu, kuru mēģināt aprēķināt.
Lūks Perijs:
=DATEDIF(B4,C4,"Y") Mainiet “Y” uz atbilstošo kolonnu, kuru mēģināt aprēķināt.
Lai iegūtu formulu JOINED, jums būs jāizmanto ArrayFormula tāpat kā iepriekš rakstā. Varat pievienot tādus vārdus kā Gadiem lai norādītu gadu rezultātus, ievietojot to aiz formulas un starp iekavām.
=ArrayFormula(datedif(B2,C2,"Y")&" Years "&datedif(B2,C2,"YM")&" months & "& datedif(B2,C2,"MD")&" days")
Iepriekš minētā formula ir paredzēta slavenībai. Tomēr, ja vēlaties tos visus izsist vienā rāvienā, kopējiet un šūnā G2 ielīmējiet šo formulu:
=ArrayFormula(datedif(B2:B4,C2:C4,"Y")&" Years "&datedif(B2:B4,C2:C4,"YM")&" months & "& datedif(B2:B4,C2:C4,"MD")&" days")
Jūsu Google lapai vajadzētu izskatīties apmēram šādi:
Diezgan glīts, vai ne? Tas tiešām ir tik vienkārši, izmantojot funkciju DATEDIF. Tagad mēs varam pāriet uz YEARFRAC funkcijas izmantošanu.
YEARFRAC funkcija
YEARFRAC funkcija ir vienkārša, lai iegūtu vienkāršus rezultātus. Tas ir tieši līdz punktam, nodrošinot gala rezultātu bez visiem papildu pievienotajiem rezultātiem gadiem, mēnešiem un dienām.
Šeit ir pamatformula, kas piemērojama tikai vienai šūnai:
=int(YEARFRAC(A1,today()))
Jūs pievienosiet dzimšanas datumu šūnai A1 un ielīmēsiet formulu B1, lai iegūtu rezultātu. Mēs izmantosim dzimšanas datumu 11.04.1983 :
Rezultāts ir 35 gadi. Vienkārši, tāpat kā izmantojot funkciju DATEDIF vienai šūnai. No šejienes mēs varam pāriet uz YEARFRAC izmantošanu ArrayFormula ietvaros. Šī formula jums ir noderīgāka, ja jums ir jāaprēķina lielu grupu vecums, piemēram, studenti, mācībspēki, komandas locekļi utt.
Mums būs jāpievieno kolonna ar dažādiem dzimšanas datumiem. Esmu atlasījis B kolonnu, jo personu vārdiem tiks izmantota A. C kolonna tiks izmantota gala rezultātiem.
Lai blakus kolonnā norādītu vecumu, mums būs jāizmanto šāda formula:
=ArrayFormula(int(yearfrac(B2:B8,today(),1)))
Lai iegūtu rezultātus, ievietojiet iepriekš minēto formulu šūnā C2.
Ja vēlaties tikai turpināt ar visu kolonnu un nedomājat, kur tā beidzas, varat pievienot nelielu formulu. Pieskarieties IF un LEN virzienā uz ArrayFormula sākumu, piemēram:
=ArrayFormula(if(len(B2:B),(int(yearfrac(B2:B,today(),1))),))
Tādējādi tiks aprēķināti visi rezultāti šajā kolonnā, sākot no B2.
